From 2079d798c91a7473f007da6b1a48664a81ad4fbf Mon Sep 17 00:00:00 2001
From: Ian Young <ian@iay.org.uk>
Date: Fri, 23 Jun 2006 09:05:15 +0000
Subject: [PATCH] Initial checkin.

---
 build/master_to_wayf.xsl | 76 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 build/master_to_wayf.xsl

diff --git a/build/master_to_wayf.xsl b/build/master_to_wayf.xsl
new file mode 100644
index 00000000..ac6a2df8
--- /dev/null
+++ b/build/master_to_wayf.xsl
@@ -0,0 +1,76 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+
+	master_to_wayf.xsl
+	
+	XSL stylesheet that takes a SAML 2.0 metadata file and filters out
+	entities marked as hidden from the WAYF.
+	
+	Author: Ian A. Young <ian@iay.org.uk>
+
+	$Id: master_to_wayf.xsl,v 1.1 2006/06/23 09:05:00 iay Exp $
+-->
+<xsl:stylesheet version="1.0"
+	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+	xmlns:ds="http://www.w3.org/2000/09/xmldsig#"
+	xmlns:shibmeta="urn:mace:shibboleth:metadata:1.0"
+	xmlns:md="urn:oasis:names:tc:SAML:2.0:metadata"
+	xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
+	xmlns:wayf="http://sdss.ac.uk/2006/06/WAYF"
+	xmlns="urn:oasis:names:tc:SAML:2.0:metadata"
+	exclude-result-prefixes="shibmeta md ds wayf">
+
+	<!--
+		Version information for this file.  Remember to peel off the dollar signs
+		before dropping the text into another versioned file.
+	-->
+	<xsl:param name="cvsId">$Id: master_to_wayf.xsl,v 1.1 2006/06/23 09:05:00 iay Exp $</xsl:param>
+
+	<!--
+		Add a comment to the start of the output file.
+	-->
+	<xsl:template match="/">
+		<xsl:comment>
+			<xsl:text>&#10;&#9;***DO NOT EDIT THIS FILE***&#10;&#10;</xsl:text>
+			<xsl:text>&#9;Converted by:&#10;&#10;&#9;</xsl:text>
+			<xsl:value-of select="substring-before(substring-after($cvsId, ': '), '$')"/>
+			<xsl:text>&#10;</xsl:text>
+		</xsl:comment>
+		<xsl:apply-templates/>
+	</xsl:template>
+
+	<!--Force UTF-8 encoding for the output.-->
+	<xsl:output omit-xml-declaration="no" method="xml" encoding="UTF-8" indent="yes"/>
+
+	<!--
+		The WAYF does not need the key authority information for the federation.
+		
+		We assume, for now, that this is the only extension on the EntitiesDescriptor
+		and just omit that entirely.  If we ever start putting other extensions in at
+		that level, this would need to be revised.
+	-->
+	<xsl:template match="md:EntitiesDescriptor/md:Extensions">
+		<!-- do nothing -->
+	</xsl:template>
+	
+	<!--
+		Any entity which has an entity-level extension element wayf:HideFromWAYF
+		is omitted from the output.
+	-->
+	<xsl:template match="md:EntityDescriptor[md:Extensions/wayf:HideFromWAYF]">
+		<!-- do nothing -->	
+	</xsl:template>
+	
+	<!--By default, copy text blocks, comments and attributes unchanged.-->
+	<xsl:template match="text()|comment()|@*">
+		<xsl:copy/>
+	</xsl:template>
+	
+	<!--By default, copy all elements from the input to the output, along with their attributes and contents.-->
+	<xsl:template match="*">
+		<xsl:copy>
+			<xsl:apply-templates select="node()|@*"/>
+		</xsl:copy>
+	</xsl:template>
+	
+</xsl:stylesheet>