md-query-saml.robot

# https://tools.ietf.org/html/draft-young-md-query-saml-09

*** Settings ***
Library    Collections
Library    Process
Library    XML
Resource    MDQ.robot
Variables    variables.py

*** Test Cases ***
2.2.1 Unique Identifier
  ${resp}=    Get Entity    baseUrl=${BASE_URL}  identifier=${ENTITY_ID_ENCODED}
  Should Be Equal As Strings    ${resp.status_code}  200  msg=MUST respond to a unique identifier

2.2.2 Transformed Identifier
  ${resp}=    Get Entity    baseUrl=${BASE_URL}  identifier={sha1}${ENTITY_ID_SHA1}
  Should Be Equal As Strings    ${resp.status_code}  200  msg=MUST respond to SHA-1 transformed identifier

3.1.1 No Entity Descriptors Returned
  ${resp}=    Get Entity    baseUrl=${BASE_URL}  identifier=foo  expectedStatus=404

3.1.2 One Entity Descriptor Returned
  ${resp}=    Get Entity    baseUrl=${BASE_URL}  identifier=${ENTITY_ID_ENCODED}
  ${root}=    Parse XML    ${resp.text}
  Should Be Equal    ${root.tag}  EntityDescriptor  msg=MUST use EntityDescriptor document element
  Should Not Contain    ${resp.text}  EntitiesDescriptor  msg=MUST NOT use EntitiesDescriptor element
  Dictionary Should Contain Item    ${resp.headers}  content-type  application/samlmetadata+xml  msg=MUST return Content-Type=application/samlmetadata+xml header

3.1.3 More Than One Entity Descriptor Returned
  [Tags]  aggregate
  ${resp}=    Get All Entities    baseUrl=${BASE_URL}
  ${root}=    Parse XML    ${resp.text}
  Should Be Equal    ${root.tag}  EntitiesDescriptor  msg=MUST use EntitiesDescriptor document element
  ${count}=    Get Element Count  ${root}  .//EntitiesDescriptor
  Should Be Equal As Integers    ${count}  0  msg=MUST NOT contain nested EntitiesDescriptor elements
  Dictionary Should Contain Item    ${resp.headers}  content-type  application/samlmetadata+xml  msg=MUST return Content-Type=application/samlmetadata+xml header