inc-ui-urls.xsl

<?xml version="1.0"?>

<xsl:stylesheet version="1.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:md="urn:oasis:names:tc:SAML:2.0:metadata"
	xmlns:mdrpi="urn:oasis:names:tc:SAML:metadata:rpi"
	xmlns:mdui="urn:oasis:names:tc:SAML:metadata:ui">

	<xsl:output method="text"/>

	<xsl:template match="*">
		<xsl:message terminate="no">
			WARNING: Unmatched element: <xsl:value-of select="name()"/>
		</xsl:message>

		<xsl:apply-templates/>
	</xsl:template>

	<xsl:template match="/">
		<xsl:apply-templates select="md:EntitiesDescriptor"/>
	</xsl:template>

	<xsl:template match="md:EntitiesDescriptor">
		<xsl:for-each select="md:EntityDescriptor">
			<xsl:if test="md:Extensions/mdrpi:RegistrationInfo/@registrationAuthority = 'https://incommon.org'">
				<xsl:apply-templates select="."/>
			</xsl:if>
		</xsl:for-each>
	</xsl:template>


	<xsl:template match="md:EntityDescriptor">
		<xsl:apply-templates select="md:IDPSSODescriptor | md:SPSSODescriptor"/>
	</xsl:template>

	<xsl:template match="md:IDPSSODescriptor">
		<xsl:value-of select="@errorURL"/><xsl:text>
</xsl:text>
		<xsl:apply-templates select="md:Extensions/mdui:UIInfo"/>
	</xsl:template>

	<xsl:template match="md:SPSSODescriptor">
		<xsl:apply-templates select="md:Extensions/mdui:UIInfo"/>
	</xsl:template>

	<xsl:template match="mdui:UIInfo">
		<xsl:value-of select="mdui:InformationURL"/><xsl:text>
</xsl:text>
		<xsl:value-of select="mdui:PrivacyStatementURL"/><xsl:text>
</xsl:text>
		<xsl:value-of select="mdui:Logo"/><xsl:text>
</xsl:text>
	</xsl:template>

</xsl:stylesheet>